[sbench]

Here's the latest I've got for the drop down tetrode files I called tetrode.txt. It has the following devices in it:
2E24, 6AC7, 6AK6, 6AN8P, 6AQ5, 6AU6, 6BH6, 6BM8, 6BQ5_EL84, 6CA7_EL34, 6E5P, 6KG6_EL509, 6L6, 6L6GC, 6SJ7, 6V6, 12BY7, 12GN7A, 807, 813, 6146, 7754_7695, 7788_E810F, D3a, EF86, SV83.

The latest additions are the 6E5P and the 7788. On those devices, I've added better modeling for the sharp break as the tube comes out of saturation into constant current region. There's a couple comments in the text files of those devices so you can see what I did, and add it to other models if you like.

Enjoy,
Stephie <3

[reVintage]

Hey Steve,

Great library! E810F and 6E5P looks interesting, must try.

The only one missing is my favourite, D3a´s little brother, E280F/7722.

[sbench]

Hi All,

OK here's another update. This one does have the 7722/E280F added. The curves I had didn't have g2 current "curves" (superimposed on the anode current curves) so I guessed a bit at that, but both pentode and triode connection reasonably match the published curves.

Enjoy,
Stephie <3

[reVintage]

Thanks Stephie,

You made my day. Will now try it with one of Daves ideas.

Also thanks for the friendship at MySpace!

[sbench]

I've redone the 7721/D3a. Added grid offset, redone the mu (G1-G2 mu was too low), fixed the screen grid current (it was too low), fixed the A-G1 capacitance, and added the limit condition for saturation current to better model the knee (like I did on the recent additions. I have left the old model in place for compatibility, and it is now in the drop-down as 7721/D3a. (the old model is still called D3a).

This version is reasonable enough to use both pentode connected and triode connected.

Enjoy.

Stephie <3

[reVintage]

Hey Stephie,

Just had the chance to try the E280F in LTSpice.

Tried it at Ua150V, Rk100ohm, meaning to reach Ug150V with Ia just above 20mA.

Unfortunately something happens when I go under Ug160V. Over 160V it works OK, though.

[Andrew]

Thanks Stephie

[sbench]

[Andrew]

Hi Stephie,

How hard would it be to derive the E180F? What's the magic here?

thanks,

-- Andrew

[reVintage]

This one is pretty basic but something to begin with:


.SUBCKT E180F 1 4 2 3
+ PARAMS: MU= 56.00 EX= 1.350 KG1= 250.0 KP=6709.19 KC= 850
+ KVB= 7.9 VCT= 0.00 RGI=2k
+ CCG=8.5P CPG1=0.03P CCP=3P
RE1 7 0 1G
RE2 8 3 1G
E1 7 0 VALUE= ; E1 BREAKS UP LONG EQUATION FOR G1.
+{V(4,3)/KP*LOG(1+EXP((1/MU+V(2,3)/V(4,3))*KP))}
G1 1 3 VALUE={(PWR(V(7),EX)+PWRS(V(7),EX))/KG1*ATAN(V(1,3)/KVB)}
G2 8 3 VALUE={(PWR(V(7),EX)+PWRS(V(7),EX))/KC*(2.5708-ATAN(V(1,3)/KVB))}
E2 8 4 VALUE={0}
RCP 1 3 1G ; FOR CONVERGENCE
C1 2 3 {CCG} ; CATHODE-GRID 1
C2 1 2 {CPG1} ; GRID 1-PLATE
C3 1 3 {CCP} ; CATHODE-PLATE
R1 2 5 {RGI} ; FOR GRID CURRENT
D3 5 3 DX ; FOR GRID CURRENT
.MODEL DX D(IS=1N RS=1 CJO=10PF TT=1N)
.ENDS

[reVintage]

Hey Stephie,
These two are 6AU6 with yours above. They show very different distortion result when driving an EL84 with anode-grid feedback. 150V/150/8mA. I know it´s not the most linear pentode. Probably yours is right as usual . The *.asc is below.

.SUBCKT 6AU6 1 4 2 3
+ PARAMS: MU=39.3 EX=1.596 KG1=1340 KP=127 KVB=6.6 ; kg2=1000
+ CCG=5.5P CPG1=.0035P CCP=5P RGI=2K
RE1 7 0 1MEG ; DUMMY SO NODE 7 HAS 2 CONNECTIONS
E1 7 0 VALUE= ; E1 BREAKS UP LONG EQUATION FOR G1.
+{V(4,3)/KP*LOG(1+EXP((1/MU+V(2,3)/V(4,3))*KP))}
G1 1 3 VALUE={(PWR(V(7),EX)+PWRS(V(7),EX))/KG1*ATAN(V(1,3)/KVB)}
*G2 4 3 VALUE={(EXP(EX*(LOG((V(4,3)/MU)+V(2,3)))))/KG2}
g2 4 3 value= {(I(G1)*140/(V(1,3) + 130))} ; models change in current with change in plate
RCP 1 3 1G ; FOR CONVERGENCE
C1 2 3 {CCG} ; CATHODE-GRID 1
C2 1 2 {CPG1} ; GRID 1-PLATE
C3 1 3 {CCP} ; CATHODE-PLATE
R1 2 5 {RGI} ; FOR GRID CURRENT
D3 5 3 DX ; FOR GRID CURRENT
.MODEL DX D(IS=1N RS=1 CJO=10PF TT=1N)
.ENDS

.SUBCKT 6AU6A A S G K
+ PARAMS: Ex=1.29250482718994 Kg1=1066.05313830636 Kp=233.038097126617
+Kvb=6.26797667003452 Mu=39.2114621352395
+ Exd=0.927382241593347 Kd=1427.5732907893 Ks=2.80629495414095 Kg=0.00189539610643784
+ CCG=5.5P CPG1=.0035P CCP=5.0P
Eat at 0 Value={limit(0.636*ATAN(V(A,K)/KVB),0,1)} ; arctangent shaping
Eme me 0 VALUE={PWR(LIMIT(V(A,K),0,2000),EXD)/KD} ; diode line
Egs gs 0 VALUE= {V(S,K)/KP*LOG(1+EXP((1/MU+V(G,K)/V(S,K))*KP))} ; effective voltage
Egs2 gs2 0 VALUE={(PWR(V(gs),EX)+PWRS(V(gs),EX))/(KG1*0.636)} ; total space current
G1 A K VALUE={LIMIT(V(gs2)*V(at),0,V(me))} ; plate current
Escrn sc 0 VALUE={KS*V(gs2)*(1.1-V(at))} ; reverse arctan shaping for screen current
G2 S K VALUE={V(sc)*LIMIT(V(S,K),0,10)/10} ; screen current
G3 G K VALUE={PWR(LIMIT(V(G,K)+1,0,1E6),1.5)*(1.25-V(at))*KG} ; grid current
C1 G K {CCG} ; CATHODE-GRID 1
C2 A G {CPG1} ; GRID 1-PLATE
C3 A K {CCP} ; CATHODE-PLATE
.ENDS 6AU6A

[sbench]

There's lots of approximations in all the models; the ones I've done are no exceptions. Because of R13, the distortion will definitely be strongly dependant on the linearity of the dynamic plate resistance of the 'AU6.

Which is the better model for that application? It's usually a good idea to Spice the plate curve set around the operating point, and use the one that literally "looks closer" to the published curves at that point.

Since the screen is constant in the circuit, that simploifies things, although it makes trying to actually implement it much more difficult.

Stephie <3

[reVintage]

Thanks, will sim the curves to see.

EDIT: Did a quickie and the 6AU6(tetrode.inc) is something like 15% off, checking the Ug=0V and ca 12% at Ug=-2V at 150V curves. Used the GE curves. Will take a closer look when I get home from my boring work.