[dave slagle]

I found the below model and cannot for the life of me get it to work. Any help greatly appreciated.

I know it uses a different pin configuration but renumbering both the model and / or the .ASY didn't help.

The error states:

Fatal Error: Too many parameters for subcircuit type "6e5p" (instance: xu1)

here is the model.

*$
.SUBCKT 6E5P 1 2 3 4 ; P G1 C G2 (Tetrode) 05-Dec-2004
+ PARAMS: MU= 42.48 EX= 1.350 KG1= 145.2 KP=191.93 KG2= 4500
+ KVB= 46.4 VCT= 0.00 RGI=1000
+ CCG=15P CPG1=0.6P CCP=2.5P
RE1 7 0 1MEG
E1 7 0 VALUE= ; E1 BREAKS UP LONG EQUATION FOR G1.
+{V(4,3)/KP*LOG(1+EXP((1/MU+V(2,3)/V(4,3))*KP))}
G1 1 3 VALUE={(PWR(V(7),EX)+PWRS(V(7),EX))/KG1*1.57*TANH(2*V(1,3)/(KVB*3.14159))}
G2 4 3 VALUE={(EXP(EX*(LOG((V(4,3)/MU)+V(2,3)))))/KG2}
RCP 1 3 1G ; FOR CONVERGENCE
C1 2 3 {CCG} ; CATHODE-GRID 1
C2 1 2 {CPG1} ; GRID 1-PLATE
C3 1 3 {CCP} ; CATHODE-PLATE
R1 2 5 {RGI} ; FOR GRID CURRENT
D3 5 3 DX ; FOR GRID CURRENT
.MODEL DX D(IS=1N RS=1 CJO=10PF TT=1N)
.ENDS

[reVintage]

Hey Dave,

Had to give it another try when I saw this post. This one works with the standard tetrode asy. Just changed the pin designations and ATAN:

.SUBCKT 6E5P 1 4 2 3
+ PARAMS: MU= 42.48 EX= 1.350 KG1= 145.2 KP=191.93 KG2= 4500
+ KVB= 46.4 VCT= 0.00 RGI=1000
+ CCG=15P CPG1=0.6P CCP=2.5P
RE1 7 0 1MEG
E1 7 0 VALUE= ; E1 BREAKS UP LONG EQUATION FOR G1.
+{V(4,3)/KP*LOG(1+EXP((1/MU+V(2,3)/V(4,3))*KP))}
G1 1 3 VALUE={(PWR(V(7),EX)+PWRS(V(7),EX))/KG1*1.57*ATAN(2*V(1,3)/(KVB*3.14159))}
G2 4 3 VALUE={(EXP(EX*(LOG((V(4,3)/MU)+V(2,3)))))/KG2}
RCP 1 3 1G ; FOR CONVERGENCE
C1 2 3 {CCG} ; CATHODE-GRID 1
C2 1 2 {CPG1} ; GRID 1-PLATE
C3 1 3 {CCP} ; CATHODE-PLATE
R1 2 5 {RGI} ; FOR GRID CURRENT
D3 5 3 DX ; FOR GRID CURRENT
.MODEL DX D(IS=1N RS=1 CJO=10PF TT=1N)
.ENDS

[dave slagle]

still get the same error.

care to post a working sample?

dave

[reVintage]

Absolutely! Will be back home in a few hours. Must doublecheck.

BY the way have you changed your tetrode .asy back to original?

EDIT: Check attachment!

[dave slagle]

It works now.

IT wasn't the model, I was using Stephies T-Curves file which has the tetrode, TriodeNH and heatered triode all on the same page and this model must have a few extra parameters in it so I was exceeding the spice limit. I deleted one of the other tubes and all was fine.

Unfortunately it isn't very close to the published curves

dave

[reVintage]

I admit, tried another and the result was the same. So all this for nothing .

[sbench]

The other problem with that model (which IIRC is generated from a java script) is that it doesn't really model grid 2 very well. I had to modify that model to make it at all useful.

Let me see if I can do anything useful on it.

Stephie

[sbench]

P.S. Anyone have a good set of curves for that critter?

[dave slagle]

here are some sheets.

[sbench]

This seems to be considerably closer to the published curves
note I've edited this. Left off the .subckt line when i cut-and-pasted the file.

.SUBCKT 6E5P 1 4 2 3
+ PARAMS: MU= 44 EX= 1.40 KG1=212 KP=200 ; KG2= 4500 kg2 isn't used, kg1 models overall gm
+ KVB= 20 VCT= 0.00 RGI=1000 ; kvb models plate resistance
+ CCG=15P CPG1=0.6P CCP=2.5P
RE1 7 0 1MEG
E1 7 0 VALUE= ; E1 BREAKS UP LONG EQUATION FOR G1.
+{V(4,3)/KP*LOG(1+EXP((1/MU+V(2,3)/V(4,3))*KP))}
G1 1 3 VALUE={limit((PWR(V(7),EX)+PWRS(V(7),EX))/KG1*1.57*ATAN(2*V(1,3)/(KVB*3.14159)),0,v(1,3)/840)} ; added limit-better models lower plate voltage limit condition
*G2 4 3 VALUE={(EXP(EX*(LOG((V(4,3)/MU)+V(2,3)))))/KG2} * this equation sucks
G2 4 3 value= {(I(G1)*32/(V(1,3) + 6))} ; this models change in current with change in plate first var changes ig2, second pushes right/left
RCP 1 3 1G ; FOR CONVERGENCE
C1 2 3 {CCG} ; CATHODE-GRID 1
C2 1 2 {CPG1} ; GRID 1-PLATE
C3 1 3 {CCP} ; CATHODE-PLATE
R1 2 5 {RGI} ; FOR GRID CURRENT
D3 5 3 DX ; FOR GRID CURRENT
.MODEL DX D(IS=1N RS=1 CJO=10PF TT=1N)
.ENDS

Enjoy,
Stephie <3