[reVintage]

Anyone who has a descent 6E5P triodestrapped model? As I couldn´t make Curve Captor work I used the Javaprogram from Dmitry Nizhegorodov. Used the curves Jim Hagerman published in RtC site.

So I have a model but need another to verify it is OK.

[dave slagle]

do you hve a direct link to the curves?

I'll run them in curve captor.

dave

[reVintage]

These are the ones I found:

http://www.hagtech.com/blog/images/6ep5_bt.jpg

http://www.hagtech.com/blog/images/6e5p63.jpg

http://www.hagtech.com/blog/images/6e5p63.jpg

Amazing linearity!

[dave slagle]

Is it safe to assume that the grid voltage steps are 1V ?

is there any associated discussion?

dave

[reVintage]

[quote="dave slagle"]Is it safe to assume that the grid voltage steps are 1V ?

is there any associated discussion?

dave[/quote]

The pink curves are with 1V steps. This is one of the links to follow:

http://www.goodsoundclub.com/Forums/ShowPost.aspx?postID=4805#4805

Here are two the models I made. Had to focus on best possible fit in the most important regions og f the curve.

.SUBCKT 6E5PT 1 2 3 ; Plate Grid Cathode
+ PARAMS: CCG=15P CGP=0.6P CCP=2.5P RGI=2000
+ MU=29.9644 KG1=596.25 KP=278.64
+ KVB=453.6 VCT=0.1320 EX=2.2742
E1 7 0 VALUE={V(1,3)/KP*LOG(1+EXP(KP*(1/MU+(VCT+V(2,3))/SQRT(KVB+V(1,3)*V(1,3)))))}
RE1 7 0 1G ; TO AVOID FLOATING NODES
G1 1 3 VALUE={(PWR(V(7),EX)+PWRS(V(7),EX))/KG1}
RCP 1 3 1G ; TO AVOID FLOATING NODES
C1 2 3 {CCG} ; CATHODE-GRID
C2 2 1 {CGP} ; GRID=PLATE
C3 1 3 {CCP} ; CATHODE-PLATE
D3 5 3 DX ; POSITIVE GRID CURRENT
R1 2 5 {RGI} ; POSITIVE GRID CURRENT
.MODEL DX D(IS=1N RS=1 CJO=10PF TT=1N)
.ENDS



.SUBCKT 6E5PT2 1 2 3 ; Plate Grid Cathode
+ PARAMS: CCG=15P CGP=0.6P CCP=2.5P RGI=2000
+ MU=30.24 KG1=705.0 KP=342.0
+ KVB=225.0 VCT=0.4120 EX=2.324
E1 7 0 VALUE={V(1,3)/KP*LOG(1+EXP(KP*(1/MU+(VCT+V(2,3))/SQRT(KVB+V(1,3)*V(1,3)))))}
RE1 7 0 1G ; TO AVOID FLOATING NODES
G1 1 3 VALUE={(PWR(V(7),EX)+PWRS(V(7),EX))/KG1}
RCP 1 3 1G ; TO AVOID FLOATING NODES
C1 2 3 {CCG} ; CATHODE-GRID
C2 2 1 {CGP} ; GRID=PLATE
C3 1 3 {CCP} ; CATHODE-PLATE
D3 5 3 DX ; POSITIVE GRID CURRENT
R1 2 5 {RGI} ; POSITIVE GRID CURRENT
.MODEL DX D(IS=1N RS=1 CJO=10PF TT=1N)
.ENDS

[dave slagle]

here is the best model i could come up with... a real quirky beast


* 6e5p LTSpice model
.subckt 6e5p P G K
Bp P K I=(0.007168081053m)*uramp(V(P,K)*ln(1.0+(0.1076589301)+exp((7.684274052)+(7.684274052)*((31.0913184)+(-62.35812906m)*V(G,K))*V(G,K)/sqrt((-2.483421354e-007)**2+(V(P,K)-(-0.01141953342))**2)))/(7.684274052))**(1.995853911)
.ends 6e5p

dave

[reVintage]

Hey Dave,
Which one did you use? I used the one I found in the link from my last post.
Yours is R3.

[Romy The Cat]

I do not know what you boys do with all those numbers. From my practice: The 6E5P/6E6P is a voltage-type a driver. The best it goes at 170-200V, 20-32mA. If you use it with anode resistor then do not use plate resistor less than 15K. The tube is not very long life, I would say one year with heavy use. The dying tube picks plates ringing. The tube is “fast” and demands to use the same accuracy as is it a high Gm pentode (stoppers, ferrite, etc…)

The Cat

[reVintage]

[quote="Romy The Cat"]I do not know what you boys do with all those numbers. From my practice: The 6E5P/6E6P is a voltage-type a driver. The best it goes at 170-200V, 20-32mA. If you use it with anode resistor then do not use plate resistor less than 15K. The tube is not very long life, I would say one year with heavy use. The dying tube picks plates ringing. The tube is “fast” and demands to use the same accuracy as is it a high Gm pentode (stoppers, ferrite, etc…)

The Cat[/quote]

Cat,
Thanks, great info from the IRL side! Your workingpoint is also what you would choose after doing sims from the "numbers", but maybe with a little lower current. A question though, how come you run the Melquiades at just above 12mA?

About the use of the numbers, keep your eyes open in the transformer section as I am about to pair the 6E5P trioded with 813 in Daves PP.

Dave,
This scale should be better as it is more like the original.

[dmitrynizh]

I ran into this thread while looking for 6e5p's triode mode curves. There are some honest attempts here to come up with a good model match but the results are not perfect in my view. 6e5p in triode mode is easy to match; just do not use Ex greater than 1.5 and make VCT negative and initailly set Kp >500 and get the best match for the first few gridlines using Mu and KG1 and then fix the corner with Kp.
I've made a pretty accurate model based on Hagerman data. I made it using my "PaintKIT" java tool, see

http://www.dmitrynizh.com/tubeparams_image.htm

Below I include the text of the model and a screenshot showing model curves over Hagerman's

Regards
Dmitry
http://www.dmitrynizh.com/


**** TRIODE_6E5P ****************************************
* Created on Mon Jun 29 19:58:11 PDT 2009 using
* tube.model.finder.PaintKIT
* Data Source: http://www.hagtech.com/blog/images/6e5p.jpg
*------------------------------------------------------------------------------
.SUBCKT TRIODE_6E5P 1 2 3 ; Plate Grid Cathode
+ PARAMS: CCG=15P CGP=0.6P CCP=2.5P RGI=2000
+ MU=32.06 KG1=139.37 KP=289.79
+ KVB=0.35 VCT=-0.39 EX=1.455
* Vp_MAX=300.0 Ip_MAX=0.1
* Vg_step=1.0 Vg_start=0.0 Vg_count=10.0
*----------------------------------------------------------------------------------
E1 7 0 VALUE={V(1,3)/KP*LOG(1+EXP(KP*(1/MU+(VCT+V(2,3))/SQRT
+ (KVB+V(1,3)*V(1,3)))))}
RE1 7 0 1G ; TO AVOID FLOATING NODES
G1 1 3 VALUE={(PWR(V(7),EX)+PWRS(V(7),EX))/KG1}
RCP 1 3 1G ; TO AVOID FLOATING NODES
C1 2 3 {CCG} ; CATHODE-GRID
C2 2 1 {CGP} ; GRID=PLATE
C3 1 3 {CCP} ; CATHODE-PLATE
D3 5 3 DX ; POSITIVE GRID CURRENT
R1 2 5 {RGI} ; POSITIVE GRID CURRENT
.MODEL DX D(IS=1N RS=1 CJO=10PF TT=1N)
.ENDS
*$

[reVintage]

Hi Dmitry,

Nice to find you here. As you probably saw I used your Java-program for the first time to the model above. Will try your advice next time.

When I look at your model it looks very nice but I wonder why you have placed your zero mA-line a little above Hagerman´s zeroline? But maybe it doesn´t matter.

[dmitrynizh]

Hi Lars,

The 6e5p plate curves have, in my view, a slight slope
(skew) alone the X axis. See attached zoomed pic. None of Sofia or Klausmobile results show a similar skew.

Hope this helps. The art of finding a good triode match at times includes
looking beyond imperfections in the data: "difficult" regions of curve
tracers, bogus interpolations in published datasheets, etc.

[Romy The Cat]

Dmitry, that is good hat you feel that 6e5p in triode mode is easy to match. Would you advise me another miniature triode that has 8W plate dissipation and can do 33time gain?

The Cat

[reVintage]

Hi Dmitrynizh,
Have just received a ten-pack of the tube in question. Will run a few of them through my old AVO to see how they measure against the earlier published curves. Its a pity though that Klausmobile havent published any curves.